Obje         EQU 23776
DarkStar     EQU #6D89
RunAddr      EQU #FF00
;
             ORG #5CE0
             ;
             ENT
             DI
             LD SP,0
             LD HL,ObjeLoc
             LD DE,RunAddr
             LD BC,#100
             LDIR
             ;
             LD IX,#4000
             LD DE,#F000-#4000
             XOR A
             ;
             JP LoadIt
;
ObjeLoc      EQU $
             ;
             ORG RunAddr,ObjeLoc
             ;
LoadIt       CALL LDBytes
             JP C DarkStar
             RST 0
             ;
LDBytes      INC D
             EX AF,AF'
             DEC D
             DI
             LD A,#09
             OUT (#FE),A
             ;
             LD HL,LDRet
             PUSH HL
             ;
             IN A,(#FE)
             RRA
             AND#20
             LD C,A
             CP A
LDBreak      JP NZ 0
             ;
LDStart      CALL LDEdge1
             JR NC LDBreak
             ;
             LD HL,#415
             ;
LDWait       DJNZ LDWait
             ;
             DEC HL
             LD A,H
             OR L
             JR NZ LDWait
             ;
             CALL LDEdge2
             JR NC LDBreak
             ;
LDLeader     LD B,#9C
             CALL LDEdge2
             JR NC LDBreak
             ;
             LD A,#C6
             CP B
             JR NC LDStart
             ;
             INC H
             JR NZ LDLeader
             ;
LDSync       LD B,#C9
             CALL LDEdge1
             JR NC LDBreak
             ;
             LD A,B
             CP #D4
             JR NC LDSync
             ;
             CALL LDEdge1
             RET NC
             ;
             LD H,0
             LD B,#B0
             JR LDMarker
;
LDLoop       EX AF,AF'
             JR NZ LDFlag
             JR NC LDLoop1
             ;
LDLoop1      LD (IX),L
             JR LDNext
;
LDFlag       RL C
             XOR L
             RET NZ
             ;
             LD A,C
             RRA
             LD C,A
             INC DE
             JR LDDec
;
LDNext       INC IX
             ;
LDDec        DEC DE
             EX AF,AF'
             LD B,#B2
             ;
LDMarker     LD L,#01
             ;
LD8Bits      CALL LDEdge2
             RET NC
             ;
             LD A,#CB
             CP B
             RL L
             LD B,#B0
             JP NC LD8Bits
             ;
             LD A,H
             XOR L
             LD H,A
             ;
             LD A,D
             OR E
             JR NZ LDLoop
             ;
             LD A,H
             CP 1
             RET
;
LDEdge2      CALL LDEdge1
             RET NC
             ;
LDEdge1      LD A,#16
             ;
LDDelay      DEC A
             JR NZ LDDelay
             ;
             OR A
LDSample     INC B
             RET Z
             ;
             LD A,#BF
             IN A,(#FE)
             RRA
             RET NC
             ;
             XOR C
             AND#20
             JR Z LDSample
             ;
             LD A,C
             XOR #F9
             LD C,A
             ;
             AND#07
             OR #08
             OUT (#FE),A
             ;
             SCF
             RET
;
LDRet        PUSH AF
             LD A,0
             OUT (#FE),A
             ;
             LD A,#BF
             IN A,(#FE)
             RRA
             JR NC LDEnd1
             ;
LDEnd        POP AF
             RET
;
LDEnd1       LD A,#FF
             POP AF
             SCF
             RET
;
             DEFM /Boring game ! Boring game !/
             DEFM /The boring game ./
             DEFM /The first bit we got tired of it/
             DEFM / so we wrote the second bit of this/
             DEFM / boring game , the boring game !/
             DEFM / Another bit , another bit , /
             DEFM /another boring bit - another bit/
             DEFM / , another bit , another final /
             DEFM /boring bit - another bit/
             DEFM / - another bit , a boring bit !/
             DEFM /Looks just like the other one ,/
             DEFM / is in fact another one , of these/
             DEFM / boring games - the boring game./
             DEFM / Oh not again !/
             DEFM / No not again !/
             DEFM / Please not again !/
             DEFM /(c) Chewrubba/